Shakkinappulan mallinnus - vaihe 2

Yläosan mallintaminen

Aloitetaan luomalla rungon päälle sylinteri, jonka halkaisija on 8 mm ja korkeus on 3 mm.

Jotta sen saa laitettua rungon päälle, niin sitä pitää nostaa translate komennolla Z-akselia pitkin 17 mm.

Lisää seuraavat rivit ihan loppuun:

translate([0,0,17]) {
    cylinder(h=3, d=8);
}

Kappale näyttää tällä hetkellä tältä:

Yläosan kolojen leikkaaminen

Kokeile lisätä heti ylimmän sylinterin luomisen jälkeen alla oleva rivi, jolla luodaan yksi kuutio Z-akselilla 2mm ylöspäin suhteessa ylimpään sylinteriin:

translate([0,0,17]) {
    cylinder(h=3, d=8);

    translate([0,0,2]) cube([10,2,2], center=true);

}

Luodaan sen jälkeen kuution luomisen ympärille silmukka, joka luo kuusi kappaletta samanlaisia kuutioita, mutta hieman eri kulmassa. Jokaista kuutiota käännetään a muuttujan verran, jonka arvo on aluksi nolla ja se kasvaa aina 60 asteen verran, kunnes sen arvo on 360. Pyörittäminen tapahtuu rotate komennolla.

translate([0,0,17]) {
    cylinder(h=3, d=8);

    for(a=[0:60:360]) {
        rotate(a) {

            translate([0,0,2]) cube([10,2,2], center=true);

        }
    }

}

Seuraavaksi leikataan juuri äsken luodut kuutiot irti ylimmästä sylinteristä difference:llä, johon tutustuttiin edellisessä ohjeessa.

translate([0,0,17]) {

    difference() {

        cylinder(h=3, d=8);

        for(a=[0:60:360]) {
            rotate(a) {
                translate([0,0,2]) cube([10,2,2], center=true);
            }
        }

    }

}

Viimeistely

Tehdään nappulasta hieman hienompi leikkaamalla pääliosasta sylinterin verran pois:

translate([0,0,17]) {

    difference() {

        difference() {
            cylinder(h=3, d=8);

            for(a=[0:60:360]) {
                rotate(a) {
                    translate([0,0,2]) cube([10,2,2], center=true);
                }
            }
        }

        cylinder(h=5, d=5);
    }

}

Tehdään vielä nappulan pinnasta hieman sileämpi.

Lisää ihan alkuun rivi:

$fn=40;

$fn on erikoismuuttuja, joka vaikuttaa monien kappaleiden tekoon. Sylinterien tapauksessa se vaikuttaa siihen, kuinka hienojakoinen kappaleesta tulee. Mitä suurempi arvo, niin sitä sileämpi pinnasta tulee.

Valmis!

Nyt voit alkaa suunnittelemaan ja tekemään omaa mallia.

Tässä ohjeessa tehdyn mallin lopullinen koodi pitäisi näyttää tältä:

$fn=40;

cylinder(h=2, d=9);

translate([0,0,2]) {
    cylinder(h=12, d1=8, d2=6);
    translate([0,0,12]) {
        cylinder(h=3, d1=6, d2=8);
    }
}

translate([0,0,17]) {
    difference() {
        difference() {
            cylinder(h=3, d=8);

            for(a=[0:60:360]) {
                rotate(a) translate([0,0,2]) cube([10,2,2], center=true);
            }
        }

        cylinder(h=5, d=5);
    }
}